Mengaktifkan gpedit.msc: Group Policy Editor di Windows 11

Manalu Zufrin
17 Jan, 2023

GPEdit.msc atau juga dikenal dengan Group Policy Editor pada Windows 11 secara default dihilangkan. Hal ini menyebabkan beberapa orang yang sering menggunakannnya untuk memperbaiki sistem Windows mengalami kesulitan. Nah, kali ini manaluzufrin akan memberitahu cara mengaktifkan kembali gpedit.msc pada Microsoft Windows 11.


Apa itu gpedit.msc ?

Mengaktifkan gpedit.msc di Windows 11


Gpedit.msc merupakan singkatan dari Group Policy Editor. Gpedit.msc ini merupakan aplikasi konfigurasi group policy yg berada di sistem Operasi Windows mulai dari Windows XP.

Kamu dapat mengakses gpedit.msc ini dengan menggunakan menu windows RUN dengan cara,

  • Tekan tombol Windows + R pada keyboard Anda untuk membuka jendela "Run".
  • Ketik "gpedit.msc" (tanpa tanda kutip) dalam kotak dialog "Run".
  • Tekan Enter atau klik OK.

Setelah melakukan langkah-langkah di atas, jendela Group Policy Editor akan terbuka. Dari sini, Kamu dapat mengonfigurasi berbagai kebijakan grup untuk komputer Kamu. 

GPEDIT.msc hanya tersedia di edisi Windows yang ditujukan untuk penggunaan bisnis dan profesional, seperti Windows 10 Pro, Enterprise, dan Education. Group Policy Editor ini mungkin tidak tersedia di edisi Windows Home.


Mengaktifkan gpedit.msc, Group Policy Editor di  Microsoft Windows 11

Error

Windows 11 secara default tidak mengaktifkan gpedit.msc atau Group Policy Editor, terutama Windows 11 Home Edition.

Solving

Untuk mengaktifkan gpedit.msc di Microsoft Windows 11 kamu hanya perlu meng-copy script dibawah ini dan mem-paste-kan nya pada notepad. Setelah itu save file nya menjadi .bat.


@echo off

>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
echo Requesting administrative privileges...
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
CD /D "%~dp0"

pushd "%~dp0"

dir /b %SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientExtensions-Package~3*.mum >List.txt
dir /b %SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientTools-Package~3*.mum >>List.txt

for /f %%i in ('findstr /i . List.txt 2^>nul') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i"
pause

Berikut ini adalah penjelasan dari barisan script untuk memasang komponen-komponen yang diperlukan untuk mengaktifkan Group Policy Editor (GPEDIT.MSC) pada sistem Windows.
  • @echo off
    Perintah yang digunakan untuk menonaktifkan penampilan perintah yang sedang dijalankan di jendela perintah. Dengan kata lain, ini membuat jendela perintah tidak menampilkan perintah yang sedang dijalankan.
  • >nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
    Perintah untuk memeriksa apakah pengguna memiliki hak administratif atau tidak. Jika pengguna tidak memiliki hak administratif, maka skrip akan memunculkan pesan yang meminta hak administratif.
  • if '%errorlevel%' NEQ '0' (...)
    Struktur pengujian kondisional yang memeriksa apakah perintah sebelumnya berhasil dieksekusi atau tidak. Jika tidak, artinya pengguna tidak memiliki hak administratif dan skrip akan meminta hak administratif.
  • :UACPrompt dan bagian berikutnya adalah bagian dari skrip yang menangani permintaan hak administratif menggunakan User Account Control (UAC) di Windows.
  • pushd "%~dp0"
    Digunakan untuk mengubah direktori kerja ke lokasi di mana skrip batch itu sendiri disimpan.
  • dir /b %SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientExtensions-Package~3*.mum >List.txt dan perintah yang serupa di bawahnya digunakan untuk mencari file .mum yang diperlukan untuk menginstal Group Policy Editor.
  • for /f %%i in ('findstr /i . List.txt 2^>nul') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i"
    Merupakan loop yang mengambil setiap baris yang sesuai dengan pencarian findstr, yang kemudian digunakan untuk menambahkan paket dengan perintah dism. Perintah dism digunakan untuk mengelola paket fitur di Windows.
  • pause
    Digunakan untuk memberhentikan skrip dan menunggu sampai pengguna menekan tombol "Enter" sebelum menutup jendela perintah.
Kemudian, kamu dapat mengeksekusi script tersebut dengan menggunakan run as administrator. Tunggu hingga windows cmd close dengan sendirinya, kemudian restart. Setelah itu kamu dapat memanggil gpedit.msc pada Windows 11 kamu seperti biasanya.
Next Post Previous Post
No Comment
Add Comment
comment url